Matching to the SM in SPheno

Aus SARAH wiki
Wechseln zu: Navigation, Suche


General

The parameters of a model have to be matched to the measured values of masses and couplings in the SM. The procedure to do this differs between a Low or High scale SPheno version:

  1. For a high-scale version one needs to match to the running parameters of the SM
  2. For a low-scale version it is common to match to the measured (pole) values of the SM parameters

Matching to running parameters

Note

The method described here was introduce in SARAH 4.9.0 and replaces previous attempts to define the matching for

General

The SPheno versions by SARAH calculate the running values for the SM gauge (g1SM, g2SM, g3SM) and Yukawa (YeSM, YdSM, YuSM) couplings as well as for the electroweak VEV (vSM) including the full one-loop corrections in the present model. This calculation is done at the scale and the input parameters which are used are

  • The running electroweak and strong coupling constants (, )
  • The measured masses of Z- and W- bosons (, )
  • The measured masses of all SM fermions (,,)
  • The entries of the CKM matrix

The exact calculation of the thresholds is explained here: SPheno_threshold_corrections.

The user can then define in the SPheno.m file the matching conditions between the running SM parameters and the parameters in the model via

DEFINITION[MatchingConditions]={
{Model parameters, SM parameter},
...
};

Matching for a One-Higgs doublet model

The simplest matching conditions are those in which the Higgs sector is the same as in the SM:

DEFINITION[MatchingConditions]={
{Ye, YeSM},
{Yd, YdSM},
{Yu, YuSM},
{g1, g1SM},
{g2, g2SM},
{g3, g3SM},
{v, vSM}
};

One can also use as short form

DEFINITION[MatchingConditions]=Default[OHDM];

In this case, SARAH makes use of the knowledge which parameters in the model correspond to the SM parameters.

Matching for a THDM-II-like model

The matching conditions for a model which has a Higgs sector as a THDM-II like the most common SUSY models for instance, would read with this definition

DEFINITION[MatchingConditions]={
{g1, g1SM},
{g2, g2SM},
{g3, g3SM},
{vd, vSM/Sqrt[1+TanBeta^2]},
{vu, TanBeta vd},
{Yu, vSM YuSM/vu},
{Yd, vSM YdSM/vd},
{Ye, vSM YeSM,vd}
};

One can also use as short form

DEFINITION[MatchingConditions]=Default[THDMII];

In this case, SARAH makes use of the knowledge which parameters in the model correspond to the SM parameters.

Matching for Models with extra gauge groups

One can use these conditions also to define the matching conditions in a model with has a gauge group which just gets broken at the SUSY scale to . The matching conditions in this case read

DEFINITION[MatchingConditions]={
 {gR, Sqrt[5/3]*g1RBLFactor*g1SM},
 {gBL, -((-g1SM^2 gRBL + gBLR gR gRBL + Sqrt[g1SM^2 (gBLR - gR)^2 (-g1SM^2 + gR^2 + gRBL^2)])/(g1SM^2 - gR^2))},
 {g2, g2SM},
 {g3, g3SM},
 {vd, vSM/Sqrt[1 + TanBeta^2]},
 {vu, VEVSM1*TanBeta},
 {Yu, YuSM vSM/vu},
 {Yd, YdSM vSM/vd},
 {Ye, YeSM vSM/vd}
};

Here, g1RBLFactor which relates and is in principle a free parameter which however can be fixed by imposing gauge coupling unification.

Matching for Models with extra Higgs doublets

Even much more complicated matching conditions can be imposed. For instance, the matching in the left-right symmetry model with two generations of bi-doublets are

where three angles are introduced to parametrize all VEVs and the neutrino Yukawa coupling is considered to be given as input. These matching conditions together with the ones in the gauge sector are defined via

(* to get simpler expressions *)
vdAux = vSM/Sqrt[1+TanBeta^2];
vuAux = TanBeta*vSM/Sqrt[1+TanBeta^2];

YuA=Transpose[YuSM]*Sqrt[1+TanBeta^2]/TanBeta
YdA=Transpose[YdSM]*Sqrt[1+TanBeta^2]
YeA=Transpose[YeSM]*Sqrt[1+TanBeta^2]

DEFINITION[MatchingConditions]={
 (* Matching for gauge couplings *)
 {gR, Sqrt[5/3]*g1RBLFactor*g1SM},
 {gBL, (gR g1SM)/Sqrt[gR^2 - g1SM^2]},
 {g2, g2SM},
 {g3, g3SM},

 (* Matching for VEVs *) 
 {vPhiu[1] , (TanBeta*TanBetaU*vSM)/(Sqrt[1 + TanBeta^2]*Sqrt[1 + TanBetaU^2])},
 {vPhid[1] , (TanBetaD*vSM)/(Sqrt[1 + TanBeta^2]*Sqrt[1 + TanBetaD^2])},
 {vPhiu[2] , (TanBeta*vSM)/(Sqrt[1 + TanBeta^2]*Sqrt[1 + TanBetaU^2])},
 {vPhid[2] , vSM/(Sqrt[1 + TanBeta^2]*Sqrt[1 + TanBetaD^2])},
 
 (* Matching for Yukawas *)
 {YQ[1;;3,1;;3,1] , -(vuAux * vPhid[2] * YuA - vdAux * vPhiu[2] * YdA)/(vPhid[2] * vPhiu[1] - vPhid[1] * vPhiu[2])},
 {YQ[1;;3,1;;3,2] ,  (vuAux * vPhid[1] * YuA - vdAux * vPhiu[1] * YdA)/(vPhid[2] * vPhiu[1] - vPhid[1] * vPhiu[2])},
 {YL[1;;3,1;;3,1] ,  ( vdAux * vPhiu[2] *YeA)/(vPhid[2] * vPhiu[1] - vPhid[1] * vPhiu[2])},
 {YL[1;;3,1;;3,2] , (- vdAux * vPhiu[1] * YeA)/(vPhid[2] * vPhiu[1] - vPhid[1] * vPhiu[2])}
};

Matching to on-shell parameters

For a low-scale SPheno version the matching to the on-shell parameters is done. The reasons are that this offers more freedom in particular for non-SUSY models, e.g.

  • Other types of the two-Higgs doublet models are supported
  • Models with flavour dependent gauge groups are supported

This matching is not done automatically. Instead the user can use the parameters

YuSM, YdSM, YeSM, g1SM, g2SM, g3SM, vSM

which contain the on-shell values. This parameters can be related to those of the model in BoundaryLowScaleInput (see Boundary conditions in SPheno).

Example

  1. SM only: the boundary conditions for the SM are
    BoundaryLowScaleInput={
     {v, vSM}, 
     {Ye, YeSM},
     {Yd, YdSM},
     {Yu, YuSM},
     {g1, g1SM},
     {g2, g2SM},
     {g3, g3SM},
     {\[Lambda],LambdaIN}
    };
    

    where LambdaIN is the only parameter which must be given via MINPAR

  2. THDM-II: the matching for the SM parameters in this model are
    BoundaryLowScaleInput={
    ...
     {v1,vSM*Cos[ArcTan[TanBeta]]},
     {v2,vSM*Sin[ArcTan[TanBeta]]},
     {Ye, YeSM*vSM/v1},
     {Yd, YdSM*vSM/v1},
     {Yu, YuSM*vSM/v2},
     {g1, g1SM},
     {g2, g2SM},
     {g3, g3SM}
    };
    

    where TanBeta is given as input in MINPAR

  3. THDM-III: here, the boundary conditions which in general can already cause flavour violation at the tree-level are
    BoundaryLowScaleInput={
    ...
     {v1,vSM*Cos[ArcTan[TanBeta]]},
     {v2,vSM*Sin[ArcTan[TanBeta]]},
     {Ye, YeSM*vSM/v1- v2/v1*epsE},
     {Yd, YdSM*vSM/v1- v2/v1*epsD},
     {Yu, YuSM*vSM/v2- v1/v2*epsU},
     {g1, g1SM},
     {g2, g2SM},
     {g3, g3SM}
    };
    

    epsX are the Yukawa-like couplings which involve compared to the THDM-II the 'wrong' Higgs doublets. Those are expected from the input blocks.

Remark

Using the on-shell parameters in the calculation is, of course, correct for pure tree-level calculations. Moreover, even for the mass spectrum calculation at one-loop this is still consistent, because one-loop thresholds are of two-loop order in the mass corrections. However, when using SPheno for the calculation of two-loop masses this leads to an inconsistency. Therefore, one should calculate the two-loop corrections only for models in wich the one-loop thresholds are included.

See also

See also